#nop This script is written for v1.99.9 and higher

#list gains clear;

#act {%1 is DEAD!!$} {#var mob %1}

#act {You are awarded %d experience points for the battle.}
{
        #math {gains[$mob][exp]} {$gains[$mob][exp] + %1};
        #math {gains[$mob][cnt]} {$gains[$mob][cnt] + 1}
}
 
#alias {rip}
{
        #showme {      Average Xp       Total Xp     #   Death List, R.I.P.};
        #showme {----------------------------------------------------------};
        
        #unvar {gains[final]};
        
        #foreach {$gains[]} {mob}
        {
                #echo {  %+14G %+14G %+5G   %s}                   
                        {$gains[$mob][exp] / $gains[$mob][cnt]}                 
                        {$gains[$mob][exp]}
                        {$gains[$mob][cnt]}
                        {$mob};            
                               
                #math gains[final][exp] $gains[final][exp] + $gains[$mob][exp];
                #math gains[final][cnt] $gains[final][cnt] + $gains[$mob][cnt] 
        };
        #showme {----------------------------------------------------------};
        
        #math tmp {$gains[final][exp] / $gains[final][cnt]};
        
        #echo {  %+14G %+14G %+5G}
                {$tmp}          
                {$gains[final][exp]}
                {$gains[final][cnt]}
}

#nop The output will look as following:

      Average Xp       Total Xp     #   Death List, R.I.P.
----------------------------------------------------------
          28,860        230,881     8   Adina
          53,391        320,349     6   Bobby
          52,631        157,894     3   Bubba                                                                       
          55,880        167,642     3   Cindy                                                                       
          45,312        271,873     6   Frank                                                                       
          60,123        240,495     4   Heidi                                                                       
          40,269        322,158     8   Jimmy                                                                       
          41,423        207,115     5   Julia                                                                       
          66,794        267,178     4   Petra                                                                       
          70,617        211,853     3   Timmy
----------------------------------------------------------
          47,948      2,397,438    50